Descriere fișier

Licențiere

Eu, deținătorul drepturilor de autor ale acestei opere, o eliberez domeniului public. Aceasta se aplică în întreaga lume. În anumite țări există posibilitatea ca acest lucru să nu fie legal posibil; în acest caz: permit oricui să utilizeze această operă în orice scop, fără nicio condiție, atâta timp cât asemenea condiții nu sunt cerute de lege.

Here is a POV-Ray source of this image:

// +FN +UA +W1200 +H1200 +A0.0 +AM2
// Used fonts: Gentium (http://scripts.sil.org/gentium )

#version 3.6;

global_settings {
  assumed_gamma 1.0
  radiosity {
    pretrace_start 0.08           // start pretrace at this size
    pretrace_end   0.02           // end pretrace at this size
    count 35                      // higher -> higher quality (1..1600) [35]
    nearest_count 5               // higher -> higher quality (1..10) [5]
    error_bound 1.8               // higher -> smoother, less accurate [1.8]
    recursion_limit 3             // how much interreflections are calculated (1..5+) [3]
    low_error_factor .5           // reduce error_bound during last pretrace step
    gray_threshold 0.0            // increase for weakening colors (0..1) [0]
    minimum_reuse 0.015           // reuse of old radiosity samples [0.015]
    brightness 1                  // brightness of radiosity effects (0..1) [1]

    adc_bailout 0.01/2
    //normal on                   // take surface normals into account [off]
    //media on                    // take media into account [off]
    //save_file "file_name"       // save radiosity data
    //load_file "file_name"       // load saved radiosity data
    //always_sample off           // turn sampling in final trace off [on]
    //max_sample 1.0              // maximum brightness of samples
  }
}

#declare A = 1.60;
#declare B = 1.00;
#declare H = 3.00;

camera
{
  perspective angle 30
  right x*image_width/image_height
  up y
  location < 0.0, 0.0,-9.0>
  look_at < 0.0, 0.0, 0.0>
}

light_source { <-1000, 400, -1000> color rgb < 1.0, 1.0, 1.0> }

background { color rgb < 1.0, 1.0, 1.0> }

#declare Cyl0 =
union
{
  difference
  {
    cylinder
    {
      < 0.0,-0.5, 0.0>, < 0.0, 0.5, 0.0>, 1.00
    }
    cylinder
    {
      < 0.0,-0.51, 0.0>, < 0.0, 0.51, 0.0>, 0.95 open
    }
    scale <A,H,B>
    texture
    {
      pigment
      {
        granite
        color_map
        {
          [0.0 color rgbt < 0.50, 0.30, 0.25, 0.40>]
          [1.0 color rgbt < 0.80, 0.80, 0.80, 0.40>]
        }
      }
      finish { brilliance 0.5 ambient 0.0 diffuse 0.7 specular 0.2 }
    }
  }

  union
  {
    sphere { < 0.0, H/2, 0.0>, 0.03 } 
    cylinder { < 0.0, H/2, 0.0>, < 0.0,-H/2, 0.0>, 0.03 }
    cylinder { <-A, H/2, 0.0>, < A, H/2, 0.0>, 0.03 }
    cylinder { < 0.0, H/2,-B>, < 0.0, H/2, B>, 0.03 }
    cylinder { <-A,-H/2, 0.0>, < A,-H/2, 0.0>, 0.03 }
    cylinder { < 0.0,-H/2,-B>, < 0.0,-H/2, B>, 0.03 }
    texture
    {
      pigment { color rgb < 0.6, 0.1, 0.1> }
      finish { ambient 0.0 diffuse 0.3 specular 0.3 }
    }
  }

  union
  {
    text
    {
      ttf "GenI102.ttf" "a" 0.1, 0
      scale 0.7
      rotate 90*x
      translate <-A/2 - 0.15, H/2 + 0.03, 0.10>
    }
    text
    {
      ttf "GenI102.ttf" "b" 0.1, 0
      scale 0.7
      rotate 90*x
      translate < B/2 - 0.15, H/2 + 0.03, 0.10>
      rotate 90*y
    }
    text
    {
      ttf "GenI102.ttf" "h" 0.1, 0
      scale 0.7
      translate <-0.40, H*5/20 - 0.20,-0.02>
      rotate 45*y
    }
    texture
    {
      pigment { color rgb < 0.6, 0.1, 0.1> }
      finish { ambient 0.0 diffuse 0.3 specular 0.3 }
    }
  }
}

object
{
  Cyl0
  rotate -45*y
  rotate -45*x
}