Această imagine a fost creată cu Persistence of Vision.

Descriere fișier

Imaginile din această galerie trebuie recreat(ă/e) sub format vectorial ca fișier SVG. Acest format are mai multe avantaje; vezi Commons:Media for cleanup pentru mai multe informații. Dacă deja este disponibilă o versiune SVG a acestei imagini, vă rugăm să o încărcați. După încărcarea pe serverele Commons a versiunii SVG, înlocuiți acest format cu formatul {{vector version available|noul nume al imaginii.svg}}.

Licențiere

Eu, deținătorul drepturilor de autor ale acestei opere, o eliberez domeniului public. Aceasta se aplică în întreaga lume. În anumite țări există posibilitatea ca acest lucru să nu fie legal posibil; în acest caz: permit oricui să utilizeze această operă în orice scop, fără nicio condiție, atâta timp cât asemenea condiții nu sunt cerute de lege.

Source

This image was created using POV-Ray for Windows, version 3.6. The image was rendered to an 1800 x 1800 square, using 0.3 anti-aliasing, and then cropped and compressed using pngcrush.

#include "colors.inc"

background { color White }

global_settings { assumed_gamma 1.0}

camera
  {
  location <0, 0, -250000>
  right <1,0,0> up <0,1,0>
  look_at  <0, 0, 0>
  angle 5/10000
  }

light_source
  {
  <0, 200000, -500000>
  color White
  area_light <50000, 0, 0>, <0, 50000, 0>, 10, 10  /* very slow, decrease 10 to 2 for experiments */
  adaptive 3
  }

#declare r_tube = 0.07;  // thickness (radius) of tube

#declare sep = 0.2; // apparent height seperation between crossing rings

#declare shiny = finish {
    ambient 0.15
    diffuse 0.85
    brilliance 2
    phong 0.25
    phong_size 7.5
    }

#declare GREEN_TORUS = torus
  {
  0.6, r_tube              // major and minor radius
  rotate -90*x      // so we can see it from the top
  translate 0.3*<cos(pi/6),sin(pi/6),0>+<0,.1,0>
  pigment { color rgb <0,0.75,0> }
  finish {shiny}
  }

#declare RED_TORUS = torus
  {
  0.6, r_tube              // major and minor radius
  rotate -90*x      // so we can see it from the top
  translate 0.3*<-cos(pi/6),sin(pi/6),0> +<0,.1,0>
  pigment { color rgb <1,0,0> }
  finish {shiny}
  }

#declare BLUE_TORUS = torus
  {
  0.6, r_tube              // major and minor radius
  rotate -90*x      // so we can see it from the top
  translate 0.3*<0,-1,0>+<0,.1,0>
  pigment { color rgb <0,0.25,1> }
  finish {shiny}
  }
  
object { RED_TORUS }
object { GREEN_TORUS }
object { BLUE_TORUS }  

intersection
  {
  object { RED_TORUS translate <0,0,-100-sep> }
  cylinder { <0,-0.3,0>, <0,-0.3,-105>, 0.25 }
  }
intersection
  {
  object { GREEN_TORUS translate <0,0,-100> }
  cylinder { <0,-0.3,0>, <0,-0.3,-105>, 0.25 }
  }

intersection
  {
  object { BLUE_TORUS translate <0,0,-100-sep> }
  cylinder { <-0.58,-0.24,-95>, <-0.58,-0.24,-105>, 0.25 }
  }
intersection
  {
  object { RED_TORUS translate <0,0,-100> }
  cylinder { <-0.58,-0.24,-95>, <-0.58,-0.24,-105>, 0.25 }
  }

intersection
  {
  object { GREEN_TORUS translate <0,0,-100-sep> }
  cylinder { <0.58,-0.24,-95>, <0.58,-0.24,-105>, 0.25 }
  }
intersection
  {
  object { BLUE_TORUS translate <0,0,-100> }
  cylinder { <0.58,-0.24,-95>, <0.58,-0.24,-105>, 0.25 }
  }

intersection
  {
  object { GREEN_TORUS translate <0,0,-100-sep> }
  cylinder { <-0.29,0.35,-95>, <-0.29,0.35,-105>, 0.25 }
  }
intersection
  {
  object { BLUE_TORUS translate <0,0,-100> }
  cylinder { <-0.29,0.35,-95>, <-0.29,0.35,-105>, 0.25 }
  }

intersection
  {
  object { BLUE_TORUS translate <0,0,-100-sep> }
  cylinder { <0.29,0.35,-95>, <0.29,0.35,-105>, 0.25 }
  }
intersection
  {
  object { RED_TORUS translate <0,0,-100> }
  cylinder { <0.29,0.35,-95>, <0.29,0.35,-105>, 0.25 }
  }

intersection
  {
  object { RED_TORUS translate <0,0,-100-sep> }
  cylinder { <0,0.85,-95>, <0,0.85,-105>, 0.25 }
  }
intersection
  {
  object { GREEN_TORUS translate <0,0,-100> }
  cylinder { <0,0.85,-95>, <0,0.85,-105>, 0.25 }
  }

plane
  {
  <0,0,-1>, -0.33
  pigment { color White }
  finish
    {
    ambient 0.35
    diffuse 0.65
    }
  }